diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/give/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/give/1.trigger.mcfunction
new file mode 100644
index 0000000000..1bbc908946
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/give/1.trigger.mcfunction
@@ -0,0 +1,7 @@
+#> asset:artifact/1191.petals_of_spring_herald/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:1191} run function asset:artifact/1191.petals_of_spring_herald/give/2.give
\ No newline at end of file
diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/give/2.give.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/give/2.give.mcfunction
new file mode 100644
index 0000000000..19543200db
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/give/2.give.mcfunction
@@ -0,0 +1,73 @@
+#> asset:artifact/1191.petals_of_spring_herald/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/1191.petals_of_spring_herald/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 1191
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "minecraft:stick"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '{"text":"春を告げる花びら","color":"#FFCCFC"}'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['{"text":"最大体力を超えて回復した対象に","color":"white"}','{"text":"超えた回復量の100%分のバリアを付与する(最大20)","color":"white"}','{"text":"春ですよー","color":"gray"}']
+# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
+    # data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
+    # data modify storage asset:artifact ConsumeItem.Count set value 1
+    # data modify storage asset:artifact ConsumeItem.Extra set value
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "hotbar"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "onHeal"
+# 効果が重複可能か否か (boolean) (オプション)
+    # data modify storage asset:artifact EnableDuplication set value
+# 神器の発動条件 (TextComponentString) (オプション)
+    data modify storage asset:artifact Condition set value '{"text":"最大体力を超える回復を与える"}'
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.Damage set value [0,0]
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.AttackType set value [Physical,Magic]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.ElementType set value [Fire,Water,Thunder,None]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.IsRangeAttack set value
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.AttackRange set value
+# MP消費量 (int)
+    data modify storage asset:artifact MPCost set value 30
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value
+# MP回復量 (int)
+    # data modify storage asset:artifact MPHealWhenHit set value
+# 神器のクールダウン (int) (オプション)
+    data modify storage asset:artifact LocalCooldown set value 400
+# 種別クールダウン ({Type: string, Duration: int}) (オプション)
+    # data modify storage asset:artifact TypeCooldown.Type set value
+    # data modify storage asset:artifact TypeCooldown.Duration set value
+# 第二種別クールダウン ({Type: string, Duration: int}) (オプション)
+    # data modify storage asset:artifact SecondaryTypeCooldown.Type set value
+    # data modify storage asset:artifact SecondaryTypeCooldown.Duration set value
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    data modify storage asset:artifact DisableCooldownMessage set value true
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    data modify storage asset:artifact DisableMPMessage set value true
+# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
+    # data modify storage asset:artifact DisableBreakSound set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value ["Flora", "Nyaptov", "Rumor"]
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give
diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/register.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/register.mcfunction
new file mode 100644
index 0000000000..436baecbb6
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/register.mcfunction
@@ -0,0 +1,8 @@
+#> asset:artifact/1191.petals_of_spring_herald/register
+#
+# 神器プールへの登録処理
+#
+# @within tag/function asset:artifact/register
+
+data modify storage asset:artifact RarityRegistry[4] append value [1191]
+data modify storage asset:artifact RarityRegistryWithColor.Green[4] append value [1191]
diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/1.trigger.mcfunction
new file mode 100644
index 0000000000..a451c8d664
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/1.trigger.mcfunction
@@ -0,0 +1,8 @@
+#> asset:artifact/1191.petals_of_spring_herald/trigger/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idの%slot%に装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{hotbar:[1191]} run function asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition
\ No newline at end of file
diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/2.check_condition.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/2.check_condition.mcfunction
new file mode 100644
index 0000000000..fa1d80a239
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/2.check_condition.mcfunction
@@ -0,0 +1,32 @@
+#> asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1191.petals_of_spring_herald/trigger/1.trigger
+
+# ID指定する
+    data modify storage asset:artifact TargetID set value 1191
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/hotbar
+# 他にアイテム等確認する場合はここに書く
+
+# IsHoT:trueならCanUsedを削除
+    execute if entity @s[tag=CanUsed] if data storage asset:context Heal{IsHoT:true} run tag @s remove CanUsed
+
+# 最大超過回復量が0ならCanUsedを削除
+    execute if entity @s[tag=CanUsed] if data storage asset:context Heal.Amount{Over:0} run tag @s remove CanUsed
+
+# 誰に超過回復量を与えたかチェックする
+    execute if entity @s[tag=CanUsed] run data modify storage asset:temp Heal.To set from storage asset:context Heal.To
+    execute if entity @s[tag=CanUsed] run data modify storage asset:temp Heal.Amounts set from storage asset:context Heal.Amounts.Over
+    execute if entity @s[tag=CanUsed] run function asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition/check_over_heal
+
+# Target.ToがないならCanUsed
+    execute if entity @s[tag=CanUsed] unless data storage asset:temp Target.To[0] run tag @s remove CanUsed
+
+# CanUsedタグをチェックして3.main.mcfunctionを実行する
+    execute if entity @s[tag=CanUsed] run function asset:artifact/1191.petals_of_spring_herald/trigger/3.main
+
+# リセット
+    data remove storage asset:temp Heal
+    data remove storage asset:temp Target
diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/2.check_condition/check_over_heal.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/2.check_condition/check_over_heal.mcfunction
new file mode 100644
index 0000000000..cb89645c52
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/2.check_condition/check_over_heal.mcfunction
@@ -0,0 +1,21 @@
+#> asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition/check_over_heal
+#
+#
+#
+# @within function
+#   asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition
+#   asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition/check_over_heal
+
+# 超過回復量の最後尾の要素をコピー
+    data modify storage asset:temp Temp set from storage asset:temp Heal.Amounts[-1]
+
+# 超過回復量が0でない場合、該当プレイヤーに既にそれ以上のバリアが付与されていなければ配列に追加する
+    execute unless data storage asset:temp {Temp:0} run function asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition/compare
+    data remove storage asset:temp Temp
+
+# 最後尾の要素を削除
+    data remove storage asset:temp Heal.To[-1]
+    data remove storage asset:temp Heal.Over[-1]
+
+# 要素がまだあれば再帰
+    execute if data storage asset:temp Heal.To[0] run function asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition/check_over_heal
diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/2.check_condition/compare.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/2.check_condition/compare.mcfunction
new file mode 100644
index 0000000000..4d5a371fed
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/2.check_condition/compare.mcfunction
@@ -0,0 +1,25 @@
+#> asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition/compare
+#
+#
+#
+# @within function asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition/check_over_heal
+
+# この神器によるバリア量 vs 回復量のN% で、回復量のほうが大きければ成功
+
+# バリア量
+    data modify storage api: Argument.UUID set value [I;1,3,344,0]
+    execute store result score $UserID Temporary run data get storage asset:temp Heal.To[-1]
+    execute as @a[tag=Receiver] if score @s UserID = $UserID Temporary run function api:entity/player/absorption/get
+    execute store result score $CurrentBarrier Temporary run data get storage api: Return.Absorption.Amount 100
+
+# 超過回復量のN%
+    execute store result score $OverHeal Temporary run data get storage asset:temp Heal.Amounts[-1] 100
+
+# 比較
+    execute if score $OverHeal Temporary > $CurrentBarrier Temporary run data modify storage asset:temp Target.To append from storage asset:temp Heal.To[-1]
+    execute if score $OverHeal Temporary > $CurrentBarrier Temporary run data modify storage asset:temp Target.Amounts append from storage asset:temp Heal.Amounts[-1]
+
+# リセット
+    scoreboard players reset $UserID Temporary
+    scoreboard players reset $OverHeal Temporary
+    scoreboard players reset $CurrentBarrier Temporary
diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/3.main.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/3.main.mcfunction
new file mode 100644
index 0000000000..66cb9bedce
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/3.main.mcfunction
@@ -0,0 +1,28 @@
+#> asset:artifact/1191.petals_of_spring_herald/trigger/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/hotbar
+
+# ここから先は神器側の効果の処理を書く
+
+# 調整班へ 以下の2箇所に超過回復量のN% を設定する箇所があります
+# asset:artifact/1191.petals_of_spring_herald/trigger/give_barrier/effect
+# asset:artifact/1191.petals_of_spring_herald/trigger/2.check_condition/compare
+
+# 演出
+    playsound entity.allay.item_taken player @a[distance=..12] ~ ~ ~ 1.2 1.5
+    playsound ogg:ambient.nether.crimson_forest.shine2 player @a[distance=..12] ~ ~ ~ 0.6 1.8
+
+# バリア付与
+    function asset:artifact/1191.petals_of_spring_herald/trigger/give_barrier/
+
+# リセット
+    scoreboard players reset $UserID Temporary
+    scoreboard players reset $CurrentBarrier Temporary
+    scoreboard players reset $OverHeal Temporary
+    scoreboard players reset $MaxBarrier Temporary
+    scoreboard players reset $Barrier Temporary
diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/_index.d.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/_index.d.mcfunction
new file mode 100644
index 0000000000..7148cbb5cd
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/_index.d.mcfunction
@@ -0,0 +1,10 @@
+#> asset:artifact/1191.petals_of_spring_herald/trigger/_index.d
+# @private
+
+#> tag
+# @within function asset:artifact/1191.petals_of_spring_herald/trigger/**
+    #declare score_holder $UserID
+    #declare score_holder $CurrentBarrier
+    #declare score_holder $OverHeal
+    #declare score_holder $MaxBarrier
+    #declare score_holder $Barrier
diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/give_barrier/.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/give_barrier/.mcfunction
new file mode 100644
index 0000000000..1c9452643a
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/give_barrier/.mcfunction
@@ -0,0 +1,19 @@
+#> asset:artifact/1191.petals_of_spring_herald/trigger/give_barrier/
+#
+#
+#
+# @within function
+#   asset:artifact/1191.petals_of_spring_herald/trigger/3.main
+#   asset:artifact/1191.petals_of_spring_herald/trigger/give_barrier/
+
+# 最後尾のUserIDの対象として実行
+    execute store result score $UserID Temporary run data get storage asset:temp Target.To[-1]
+    execute as @a[tag=Receiver] if score @s UserID = $UserID Temporary run function asset:artifact/1191.petals_of_spring_herald/trigger/give_barrier/effect
+    scoreboard players reset $UserID Temporary
+
+# 最後尾の要素を削除
+    data remove storage asset:temp Target.To[-1]
+    data remove storage asset:temp Target.Amounts[-1]
+
+# 再帰
+    execute if data storage asset:temp Target.To[0] run function asset:artifact/1191.petals_of_spring_herald/trigger/give_barrier/
diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/give_barrier/effect.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/give_barrier/effect.mcfunction
new file mode 100644
index 0000000000..b50f3d6799
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/give_barrier/effect.mcfunction
@@ -0,0 +1,23 @@
+#> asset:artifact/1191.petals_of_spring_herald/trigger/give_barrier/effect
+#
+#
+#
+# @within function asset:artifact/1191.petals_of_spring_herald/trigger/give_barrier/
+
+# 演出
+    execute at @s run function asset:artifact/1191.petals_of_spring_herald/trigger/give_barrier/vfx
+
+# 超過回復量のN%を取得 (e2)
+    execute store result score $OverHeal Temporary run data get storage asset:temp Target.Amounts[-1] 100
+
+# 調整班用
+    # バリアの効果時間
+        data modify storage api: Argument.Duration set value 600
+    # バリア最大値(e2)
+        scoreboard players set $MaxBarrier Temporary 2000
+
+# エフェクト付与
+    data modify storage api: Argument.ID set value 344
+    execute store result storage api: Argument.FieldOverride.Barrier float 0.01 run scoreboard players operation $OverHeal Temporary < $MaxBarrier Temporary
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
diff --git a/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/give_barrier/vfx.mcfunction b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/give_barrier/vfx.mcfunction
new file mode 100644
index 0000000000..4bdf2c38c0
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1191.petals_of_spring_herald/trigger/give_barrier/vfx.mcfunction
@@ -0,0 +1,7 @@
+#> asset:artifact/1191.petals_of_spring_herald/trigger/give_barrier/vfx
+#
+#
+#
+# @within function asset:artifact/1191.petals_of_spring_herald/trigger/give_barrier/effect
+
+    particle cherry_leaves ~ ~1.2 ~ 1.5 0.4 1.5 0 30 normal @a
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/_/end.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/_/end.mcfunction
new file mode 100644
index 0000000000..16f7f84e37
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/_/end.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0344.spring_wind/_/end
+#
+# Effectの効果の終了時に実行されるfunction
+#
+# @within tag/function asset:effect/end
+
+execute if data storage asset:context {id:344} run function asset:effect/0344.spring_wind/end/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/_/given.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/_/given.mcfunction
new file mode 100644
index 0000000000..1bf4ec657b
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/_/given.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0344.spring_wind/_/given
+#
+# Effectが付与された時に実行されるfunction
+#
+# @within tag/function asset:effect/given
+
+execute if data storage asset:context {id:344} run function asset:effect/0344.spring_wind/given/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/_/re-given.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/_/re-given.mcfunction
new file mode 100644
index 0000000000..8e0d99807a
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/_/re-given.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0344.spring_wind/_/re-given
+#
+# Effectが上書きされた時に実行されるfunction
+#
+# @within tag/function asset:effect/re-given
+
+execute if data storage asset:context {id:344} run function asset:effect/0344.spring_wind/re-given/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/_/register.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/_/register.mcfunction
new file mode 100644
index 0000000000..ab7710b94f
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/_/register.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0344.spring_wind/_/register
+#
+#
+#
+# @within tag/function asset:effect/register
+
+execute if data storage asset:context {id:344} run function asset:effect/0344.spring_wind/register
\ No newline at end of file
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/_/remove.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/_/remove.mcfunction
new file mode 100644
index 0000000000..a1c423828a
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/_/remove.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0344.spring_wind/_/remove
+#
+# Effectが神器や牛乳によって削除された時に実行されるfunction
+#
+# @within tag/function asset:effect/remove
+
+execute if data storage asset:context {id:344} run function asset:effect/0344.spring_wind/remove/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/barrier/add.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/barrier/add.mcfunction
new file mode 100644
index 0000000000..f5a268897f
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/barrier/add.mcfunction
@@ -0,0 +1,14 @@
+#> asset:effect/0344.spring_wind/barrier/add
+#
+#
+#
+# @within function
+#   asset:effect/0344.spring_wind/given/
+#   asset:effect/0344.spring_wind/re-given/
+
+# バリア設定
+    data modify storage api: Argument.Amount set from storage asset:context this.Barrier
+    data modify storage api: Argument.UUID set from storage asset:context this.UUID
+    data modify storage api: Argument.Priority set value 1
+    data modify storage api: Argument.WipedCallback set value "asset:effect/0344.spring_wind/barrier/break"
+    function api:entity/player/absorption/add
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/barrier/break.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/barrier/break.mcfunction
new file mode 100644
index 0000000000..c667d1ce5d
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/barrier/break.mcfunction
@@ -0,0 +1,10 @@
+#> asset:effect/0344.spring_wind/barrier/break
+#
+#
+#
+# @within function lib:score_to_health_wrapper/core/absorb_damage/call_wiped_callback.m
+
+# このエフェクトを削除
+    data modify storage api: Argument.ID set value 344
+    function api:entity/mob/effect/remove/from_id
+    function api:entity/mob/effect/reset
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/barrier/remove.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/barrier/remove.mcfunction
new file mode 100644
index 0000000000..7661348d42
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/barrier/remove.mcfunction
@@ -0,0 +1,12 @@
+#> asset:effect/0344.spring_wind/barrier/remove
+#
+#
+#
+# @within function
+#   asset:effect/0344.spring_wind/end/
+#   asset:effect/0344.spring_wind/re-given/
+#   asset:effect/0344.spring_wind/remove/
+
+# バリアを削除する
+    data modify storage api: Argument.UUID set from storage asset:context this.UUID
+    function api:entity/player/absorption/remove
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/end/.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/end/.mcfunction
new file mode 100644
index 0000000000..73f028e604
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/end/.mcfunction
@@ -0,0 +1,8 @@
+#> asset:effect/0344.spring_wind/end/
+#
+# Effectの効果が切れた時の処理
+#
+# @within function asset:effect/0344.spring_wind/_/end
+
+# バリアを削除
+    function asset:effect/0344.spring_wind/barrier/remove
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/given/.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/given/.mcfunction
new file mode 100644
index 0000000000..48b53a24c5
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/given/.mcfunction
@@ -0,0 +1,8 @@
+#> asset:effect/0344.spring_wind/given/
+#
+# Effectが付与された時の処理
+#
+# @within function asset:effect/0344.spring_wind/_/given
+
+# バリアを付与
+    function asset:effect/0344.spring_wind/barrier/add
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/re-given/.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/re-given/.mcfunction
new file mode 100644
index 0000000000..1b445b7a4f
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/re-given/.mcfunction
@@ -0,0 +1,9 @@
+#> asset:effect/0344.spring_wind/re-given/
+#
+# Effectが上書きされた時の処理
+#
+# @within function asset:effect/0344.spring_wind/_/re-given
+
+# バリアを更新
+    function asset:effect/0344.spring_wind/barrier/remove
+    function asset:effect/0344.spring_wind/barrier/add
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/register.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/register.mcfunction
new file mode 100644
index 0000000000..f8112f36f5
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/register.mcfunction
@@ -0,0 +1,40 @@
+#> asset:effect/0344.spring_wind/register
+#
+# Effectのデータを指定
+#
+# @within function asset:effect/0344.spring_wind/_/register
+
+# ExtendsSafe (boolean) (default = false)
+    # data modify storage asset:effect ExtendsSafe set value true
+# ID (int)
+    data modify storage asset:effect ID set value 344
+# 名前 (TextComponentString)
+    data modify storage asset:effect Name set value '{"text":"春風","color":"#FFCCFC"}'
+# 説明文 (TextComponentString[])
+    data modify storage asset:effect Description set value ['{"text":"最大体力を超えた回復量に比例したバリアを得る","color":"white"}']
+# 効果時間 (int) (default = API || error)
+    # data modify storage asset:effect Duration set value
+# スタック (int) (default = API || 1)
+    # data modify storage asset:effect Stack set value
+# 効果時間の操作方法 (default = API || "replace")
+    # data modify storage asset:effect DurationOperation set value
+# スタックの操作方法 (default = API || "replace")
+    # data modify storage asset:effect StackOperation set value
+# 最大効果時間 (int) (default = 2147483647)
+    # data modify storage asset:effect MaxDuration set value
+# 最大スタック (int) (default = 2147483647)
+    data modify storage asset:effect MaxStack set value 1
+# 悪い効果か否か (boolean)
+    data modify storage asset:effect IsBadEffect set value false
+# 死亡時のエフェクトの処理 (default = "remove")
+    # data modify storage asset:effect ProcessOnDied set value
+# 消すのに必要なレベル (int) (default = 1)
+    data modify storage asset:effect RequireClearLv set value 3
+# エフェクトをUIに表示するか (boolean) (default = true)
+    # data modify storage asset:effect Visible set value
+# エフェクトのスタックををUIに表示するか (boolean) (default = true)
+    data modify storage asset:effect StackVisible set value false
+
+# フィールド
+    data modify storage asset:effect Field.UUID set value [I;1,3,344,0]
+    data modify storage asset:effect Field.Barrier set value 10
diff --git a/Asset/data/asset/functions/effect/0344.spring_wind/remove/.mcfunction b/Asset/data/asset/functions/effect/0344.spring_wind/remove/.mcfunction
new file mode 100644
index 0000000000..0bd7072278
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0344.spring_wind/remove/.mcfunction
@@ -0,0 +1,8 @@
+#> asset:effect/0344.spring_wind/remove/
+#
+# Effectが削除された時の処理
+#
+# @within function asset:effect/0344.spring_wind/_/remove
+
+# バリアを削除
+    function asset:effect/0344.spring_wind/barrier/remove
diff --git a/Asset/data/asset/tags/functions/artifact/give.json b/Asset/data/asset/tags/functions/artifact/give.json
index 6d62d7b380..22e427afa0 100644
--- a/Asset/data/asset/tags/functions/artifact/give.json
+++ b/Asset/data/asset/tags/functions/artifact/give.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1191.petals_of_spring_herald/give/1.trigger",
         "asset:artifact/1144.cradle_of_azure_moon/give/1.trigger",
         "asset:artifact/1317.oblivious_feather/give/1.trigger",
         "asset:artifact/1324.balance_star/give/1.trigger",
diff --git a/Asset/data/asset/tags/functions/artifact/heal.json b/Asset/data/asset/tags/functions/artifact/heal.json
index 5864bb54ee..44984ae464 100644
--- a/Asset/data/asset/tags/functions/artifact/heal.json
+++ b/Asset/data/asset/tags/functions/artifact/heal.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1191.petals_of_spring_herald/trigger/1.trigger",
         "asset:artifact/0566.great_sage_helmet/heal/1.trigger",
         "asset:artifact/0258.cat_dream_pillow/trigger/1.trigger",
         "asset:artifact/1108.white_lily_of_priestess/trigger/1.trigger",
diff --git a/Asset/data/asset/tags/functions/artifact/register.json b/Asset/data/asset/tags/functions/artifact/register.json
index cbb226dca8..a26fd8ea11 100644
--- a/Asset/data/asset/tags/functions/artifact/register.json
+++ b/Asset/data/asset/tags/functions/artifact/register.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1191.petals_of_spring_herald/register",
         "asset:artifact/1144.cradle_of_azure_moon/register",
         "asset:artifact/1317.oblivious_feather/register",
         "asset:artifact/1324.balance_star/register",
diff --git a/Asset/data/asset/tags/functions/effect/end.json b/Asset/data/asset/tags/functions/effect/end.json
index 81710cbe5a..323dd322a6 100644
--- a/Asset/data/asset/tags/functions/effect/end.json
+++ b/Asset/data/asset/tags/functions/effect/end.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:effect/0344.spring_wind/_/end",
         "asset:effect/0025.levitation/_/end",
         "asset:effect/0621.loyalty_shield/_/end",
         "asset:effect/0653.absolute_drive/_/end",
diff --git a/Asset/data/asset/tags/functions/effect/given.json b/Asset/data/asset/tags/functions/effect/given.json
index c20c6c5587..9324b3a712 100644
--- a/Asset/data/asset/tags/functions/effect/given.json
+++ b/Asset/data/asset/tags/functions/effect/given.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:effect/0344.spring_wind/_/given",
         "asset:effect/0315.charge_of_aurora_scythe/_/given",
         "asset:effect/0621.loyalty_shield/_/given",
         "asset:effect/0653.absolute_drive/_/given",
diff --git a/Asset/data/asset/tags/functions/effect/re-given.json b/Asset/data/asset/tags/functions/effect/re-given.json
index baf0379fc2..8cd9997dc7 100644
--- a/Asset/data/asset/tags/functions/effect/re-given.json
+++ b/Asset/data/asset/tags/functions/effect/re-given.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:effect/0344.spring_wind/_/re-given",
         "asset:effect/0029.poison/_/re-given",
         "asset:effect/0030.wither/_/re-given",
         "asset:effect/0621.loyalty_shield/_/re-given",
diff --git a/Asset/data/asset/tags/functions/effect/register.json b/Asset/data/asset/tags/functions/effect/register.json
index 2df8839cf1..90c0953277 100644
--- a/Asset/data/asset/tags/functions/effect/register.json
+++ b/Asset/data/asset/tags/functions/effect/register.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:effect/0344.spring_wind/_/register",
         "asset:effect/0025.levitation/_/register",
         "asset:effect/0247.great_demon_armor/_/register",
         "asset:effect/0246.flame_devil_armor/_/register",
@@ -167,4 +168,4 @@
         "asset:effect/0007.defense_base_debuff/_/register",
         "asset:effect/0258.spirit_melody/_/register"
     ]
-}
+}
\ No newline at end of file
diff --git a/Asset/data/asset/tags/functions/effect/remove.json b/Asset/data/asset/tags/functions/effect/remove.json
index 3e8ceea4eb..c6f1890255 100644
--- a/Asset/data/asset/tags/functions/effect/remove.json
+++ b/Asset/data/asset/tags/functions/effect/remove.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:effect/0344.spring_wind/_/remove",
         "asset:effect/0025.levitation/_/remove",
         "asset:effect/0245.flame_hunter_attire/_/remove",
         "asset:effect/0255.kaguya_s_difficulties/_/remove",