ProjectTSB · Lapis-LJA · Apr 18, 2026 · Apr 19, 2026 · Apr 19, 2026 · Apr 19, 2026
diff --git a/Asset/data/asset/functions/artifact/1316.blight_flowgun/give/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1316.blight_flowgun/give/1.trigger.mcfunction
@@ -0,0 +1,7 @@
+#> asset:artifact/1316.blight_flowgun/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:1316} run function asset:artifact/1316.blight_flowgun/give/2.give
diff --git a/Asset/data/asset/functions/artifact/1316.blight_flowgun/give/2.give.mcfunction b/Asset/data/asset/functions/artifact/1316.blight_flowgun/give/2.give.mcfunction
@@ -0,0 +1,68 @@
+#> asset:artifact/1316.blight_flowgun/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/1316.blight_flowgun/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 1316
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "minecraft:carrot_on_a_stick"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '{"text":"穢れ吹き矢","color":"#ab2f6e"}'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['{"text":"前方に穢れに染まった矢を飛ばし","color":"white"}','{"translate":"対象に穢れを%1$s秒間付与する","color":"white","with":[{"text":"8"}]}']
+# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
+    data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.arrow"}'
+    data modify storage asset:artifact ConsumeItem.Count set value 1
+    # data modify storage asset:artifact ConsumeItem.Extra set value
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "mainhand"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "onClick"
+# 神器の発動条件 (TextComponentString) (オプション)
+    # data modify storage asset:artifact Condition set value
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.Damage set value "400+100x16"
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackType set value [Magic]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.ElementType set value [None]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.IsRangeAttack set value "never"
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackRange set value 20
+# MP消費量 (int)
+    data modify storage asset:artifact MPCost set value 80
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value
+# MP回復量 (int)
+    # data modify storage asset:artifact MPHealWhenHit set value
+# 神器のクールダウン (int) (オプション)
+    # data modify storage asset:artifact LocalCooldown set value
+# 種別クールダウン ({Type: string, Duration: int}) (オプション)
+    data modify storage asset:artifact TypeCooldown.Type set value "longRange"
+    data modify storage asset:artifact TypeCooldown.Duration set value 40
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableCooldownMessage set value
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableMPMessage set value
+# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
+    # data modify storage asset:artifact DisableBreakSound set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value ["Urban", "Wi-ki", "Rumor"]
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give
diff --git a/Asset/data/asset/functions/artifact/1316.blight_flowgun/register.mcfunction b/Asset/data/asset/functions/artifact/1316.blight_flowgun/register.mcfunction
@@ -0,0 +1,7 @@
+#> asset:artifact/1316.blight_flowgun/register
+#
+# 神器プールへの登録処理
+#
+# @within tag/function asset:artifact/register
+
+#data modify storage asset:artifact RarityRegistry[4] append value [1316]
diff --git a/Asset/data/asset/functions/artifact/1316.blight_flowgun/trigger/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1316.blight_flowgun/trigger/1.trigger.mcfunction
@@ -0,0 +1,8 @@
+#> asset:artifact/1316.blight_flowgun/trigger/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{mainhand:1316} run function asset:artifact/1316.blight_flowgun/trigger/2.check_condition
diff --git a/Asset/data/asset/functions/artifact/1316.blight_flowgun/trigger/2.check_condition.mcfunction b/Asset/data/asset/functions/artifact/1316.blight_flowgun/trigger/2.check_condition.mcfunction
@@ -0,0 +1,26 @@
+#> asset:artifact/1316.blight_flowgun/trigger/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1316.blight_flowgun/trigger/1.trigger
+
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/mainhand
+# 他にアイテム等確認する場合はここに書く
+
+#> Private
+# @private
+    #declare score_holder $Count
+
+# CanUsedでないならreturn
+    execute if entity @s[tag=!CanUsed] run return fail
+
+# 矢の数をチェック
+    execute store result score $Count Temporary run clear @s #arrows 0
+    execute unless score $Count Temporary matches 1.. run function lib:message/artifact/dont_have_require_items
+    execute unless score $Count Temporary matches 1.. run tag @s remove CanUsed
+    scoreboard players reset $Count Temporary
+    execute if entity @s[tag=!CanUsed] run return fail
+
+# 3.main.mcfunctionを実行する
+    function asset:artifact/1316.blight_flowgun/trigger/3.main
diff --git a/Asset/data/asset/functions/artifact/1316.blight_flowgun/trigger/3.main.mcfunction b/Asset/data/asset/functions/artifact/1316.blight_flowgun/trigger/3.main.mcfunction
@@ -0,0 +1,40 @@
+#> asset:artifact/1316.blight_flowgun/trigger/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/1316.blight_flowgun/trigger/2.check_condition
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/mainhand
+
+# ここから先は神器側の効果の処理を書く
+
+# 調整班へ
+# もしエフェクトの属性を弄る、ということがあるならエフェクトの説明も忘れず変えてください
+
+# 矢を消費
+    clear @s #arrows 1
+
+# 演出
+    playsound minecraft:entity.arrow.shoot player @a ~ ~ ~ 1 0.9
+
+# 数値設定
+    # 矢のダメージ
+        data modify storage api: Argument.FieldOverride.Damage set value 400f
+    # 毒ダメージ
+        data modify storage api: Argument.FieldOverride.PoisonDamage set value 100f
+    # デバフの効果時間
+        data modify storage api: Argument.FieldOverride.Duration set value 160
+    # ダメージ間隔
+        data modify storage api: Argument.FieldOverride.Interval.Max set value 10
+    # 弾速 (1tickにつき(値 * 0.5)ブロック)
+        data modify storage api: Argument.FieldOverride.Speed set value 5
+    # 最大射程 ( (値/2)ブロックが最大射程)
+        data modify storage api: Argument.FieldOverride.Range set value 40
+
+# 矢を発射
+    data modify storage api: Argument.ID set value 1157
+    data modify storage api: Argument.FieldOverride.AttackType set value "Magic"
+    data modify storage api: Argument.FieldOverride.ElementType set value "None"
+    execute store result storage api: Argument.FieldOverride.UserID int 1 run scoreboard players get @s UserID
+    execute anchored eyes positioned ^ ^-0.1 ^ run function api:object/summon
diff --git a/Asset/data/asset/functions/effect/0353.blight/_/given.mcfunction b/Asset/data/asset/functions/effect/0353.blight/_/given.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0353.blight/_/given
+#
+# Effectが付与された時に実行されるfunction
+#
+# @within tag/function asset:effect/given
+
+execute if data storage asset:context {id:353} run function asset:effect/0353.blight/given/
diff --git a/Asset/data/asset/functions/effect/0353.blight/_/re-given.mcfunction b/Asset/data/asset/functions/effect/0353.blight/_/re-given.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0353.blight/_/re-given
+#
+# Effectが上書きされた時に実行されるfunction
+#
+# @within tag/function asset:effect/re-given
+
+execute if data storage asset:context {id:353} run function asset:effect/0353.blight/re-given/
diff --git a/Asset/data/asset/functions/effect/0353.blight/_/register.mcfunction b/Asset/data/asset/functions/effect/0353.blight/_/register.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0353.blight/_/register
+#
+#
+#
+# @within tag/function asset:effect/register
+
+execute if data storage asset:context {id:353} run function asset:effect/0353.blight/register
diff --git a/Asset/data/asset/functions/effect/0353.blight/_/tick.mcfunction b/Asset/data/asset/functions/effect/0353.blight/_/tick.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0353.blight/_/tick
+#
+# Effectが発動している間毎tick実行されるfunction
+#
+# @within tag/function asset:effect/tick
+
+execute if data storage asset:context {id:353} run function asset:effect/0353.blight/tick/
diff --git a/Asset/data/asset/functions/effect/0353.blight/given/.mcfunction b/Asset/data/asset/functions/effect/0353.blight/given/.mcfunction
@@ -0,0 +1,8 @@
+#> asset:effect/0353.blight/given/
+#
+# Effectが付与された時の処理
+#
+# @within function asset:effect/0353.blight/_/given
+
+# 初期化
+    function asset:effect/0353.blight/init/
diff --git a/Asset/data/asset/functions/effect/0353.blight/init/.mcfunction b/Asset/data/asset/functions/effect/0353.blight/init/.mcfunction
@@ -0,0 +1,10 @@
+#> asset:effect/0353.blight/init/
+#
+#
+#
+# @within function
+#   asset:effect/0353.blight/given/
+#   asset:effect/0353.blight/re-given/
+
+# Tickを初期化
+    data modify storage asset:context this.Interval._ set from storage asset:context this.Interval.Max
diff --git a/Asset/data/asset/functions/effect/0353.blight/re-given/.mcfunction b/Asset/data/asset/functions/effect/0353.blight/re-given/.mcfunction
@@ -0,0 +1,8 @@
+#> asset:effect/0353.blight/re-given/
+#
+# Effectが上書きされた時の処理
+#
+# @within function asset:effect/0353.blight/_/re-given
+
+# 初期化
+    function asset:effect/0353.blight/init/
diff --git a/Asset/data/asset/functions/effect/0353.blight/register.mcfunction b/Asset/data/asset/functions/effect/0353.blight/register.mcfunction
@@ -0,0 +1,42 @@
+#> asset:effect/0353.blight/register
+#
+# Effectのデータを指定
+#
+# @within function asset:effect/0353.blight/_/register
+
+# ExtendsSafe (boolean) (default = false)
+    # data modify storage asset:effect ExtendsSafe set value true
+# ID (int)
+    data modify storage asset:effect ID set value 353
+# 名前 (TextComponentString)
+    data modify storage asset:effect Name set value '{"text":"穢れ","color":"#ab2f6e"}'
+# 説明文 (TextComponentString[])
+    data modify storage asset:effect Description set value ['{"text":"継続的に魔法無属性ダメージを受ける"}']
+# 効果時間 (int) (default = API || error)
+    # data modify storage asset:effect Duration set value
+# スタック (int) (default = API || 1)
+    # data modify storage asset:effect Stack set value
+# 効果時間の操作方法 (default = API || "replace")
+    # data modify storage asset:effect DurationOperation set value
+# スタックの操作方法 (default = API || "replace")
+    # data modify storage asset:effect StackOperation set value
+# 最大効果時間 (int) (default = 2147483647)
+    # data modify storage asset:effect MaxDuration set value
+# 最大スタック (int) (default = 2147483647)
+    data modify storage asset:effect MaxStack set value 1
+# 悪い効果か否か (boolean)
+    data modify storage asset:effect IsBadEffect set value true
+# 死亡時のエフェクトの処理 (default = "remove")
+    # data modify storage asset:effect ProcessOnDied set value
+# 消すのに必要なレベル (int) (default = 1)
+    data modify storage asset:effect RequireClearLv set value 3
+# エフェクトをUIに表示するか (boolean) (default = true)
+    # data modify storage asset:effect Visible set value
+# エフェクトのスタックををUIに表示するか (boolean) (default = true)
+    data modify storage asset:effect StackVisible set value false
+
+# フィールド
+    data modify storage asset:effect Field.Interval._ set value 0
+    data modify storage asset:effect Field.Interval.Max set value 10
+    data modify storage asset:effect Field.Damage set value 1
+    data modify storage asset:effect Field.AppliedFrom set value -1
diff --git a/Asset/data/asset/functions/effect/0353.blight/tick/.mcfunction b/Asset/data/asset/functions/effect/0353.blight/tick/.mcfunction
@@ -0,0 +1,11 @@
+#> asset:effect/0353.blight/tick/
+#
+# Effectのtick処理
+#
+# @within function asset:effect/0353.blight/_/tick
+
+# デクリメント
+    execute store result storage asset:context this.Interval._ int 0.9999999999 run data get storage asset:context this.Interval._
+# 1秒毎にダメージ
+    execute if data storage asset:context this.Interval{_:0} run function asset:effect/0353.blight/tick/deal_damage
+    execute if data storage asset:context this.Interval{_:0} run data modify storage asset:context this.Interval._ set from storage asset:context this.Interval.Max
diff --git a/Asset/data/asset/functions/effect/0353.blight/tick/deal_damage.mcfunction b/Asset/data/asset/functions/effect/0353.blight/tick/deal_damage.mcfunction
@@ -0,0 +1,21 @@
+#> asset:effect/0353.blight/tick/deal_damage
+#
+#
+#
+# @within function asset:effect/0353.blight/tick/
+
+#> Private
+# @private
+    #declare score_holder $AppliedFrom
+
+# ダメージ
+    execute store result score $AppliedFrom Temporary run data get storage asset:context this.AppliedFrom
+    data modify storage api: Argument.Damage set from storage asset:context this.Damage
+    data modify storage api: Argument.AttackType set value "Magic"
+    data modify storage api: Argument.ElementType set value "None"
+    data modify storage api: Argument.ApplyTrigger set value false
+    execute as @a if score @s UserID = $AppliedFrom Temporary run function api:damage/modifier
+    function api:damage/
+    function api:damage/reset
+# リセット
+    scoreboard players reset $AppliedFrom Temporary
diff --git a/Asset/data/asset/functions/object/1157.blight_flowgun/pre_hit/.mcfunction b/Asset/data/asset/functions/object/1157.blight_flowgun/pre_hit/.mcfunction
@@ -0,0 +1,19 @@
+#> asset:object/1157.blight_flowgun/pre_hit/
+#
+# 継承先などから実行される処理
+#
+# @within asset:object/alias/1157/pre_hit
+
+#> Private
+# @private
+    #declare tag 1009.Target
+
+# エフェクト付与
+    data modify storage api: Argument.ID set value 353
+    data modify storage api: Argument.Duration set from storage asset:context this.Duration
+    data modify storage api: Argument.FieldOverride.Damage set from storage asset:context this.PoisonDamage
+    data modify storage api: Argument.FieldOverride.AppliedFrom set from storage asset:context this.UserID
+    data modify storage api: Argument.FieldOverride.Interval.Max set from storage asset:context this.Interval.Max
+    # data modify storage api: Argument.FieldOverride.AdditionalMPHeal set from storage asset:context this.AdditionalMPHeal
+    execute positioned ~-0.5 ~-0.5 ~-0.5 as @e[type=#lib:living_without_player,tag=1009.Target,dx=0] run function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
diff --git a/Asset/data/asset/functions/object/1157.blight_flowgun/recursive/.mcfunction b/Asset/data/asset/functions/object/1157.blight_flowgun/recursive/.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/1157.blight_flowgun/recursive/
+#
+# 継承先などから実行される処理
+#
+# @within asset:object/alias/1157/recursive
+
+# 演出
+    execute if predicate lib:random_pass_per/30 run particle entity_effect ~ ~ ~ 0.671 0.184 0.431 1 0 normal
diff --git a/Asset/data/asset/functions/object/1157.blight_flowgun/register.mcfunction b/Asset/data/asset/functions/object/1157.blight_flowgun/register.mcfunction
@@ -0,0 +1,26 @@
+#> asset:object/1157.blight_flowgun/register
+#
+# Objectのデータを指定
+#
+# @within function asset:object/alias/1157/register
+
+# 継承(オプション)
+    data modify storage asset:object Extends append value 1009
+    function asset:object/extends
+# 他のObjectに継承されることを許可するか (boolean) (オプション)
+    # data modify storage asset:object ExtendsSafe set value
+# 継承されることを前提とした、抽象的なObjectであるかどうか(boolean)
+    data modify storage asset:object IsAbstract set value false
+# Tickするかどうか(boolean) (オプション)
+    # data modify storage asset:object IsTicking set value
+
+# ID (int)
+    data modify storage asset:object ID set value 1157
+# フィールド(オプション)
+    data modify storage asset:object Field.Color set value 11218798
+    data modify storage asset:object Field.ShowCritParticle set value false
+    data modify storage asset:object Field.Range set value 40
+    data modify storage asset:object Field.Speed set value 5
+    data modify storage asset:object Field.Damage set value 1
+    data modify storage asset:object Field.PoisonDamage set value 1
+    # data modify storage asset:object Field.AdditionalMPHeal set value 1
diff --git a/Asset/data/asset/functions/object/alias/1157/pre_hit.mcfunction b/Asset/data/asset/functions/object/alias/1157/pre_hit.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/alias/1157/pre_hit
+#
+# メソッド処理のエイリアス
+#
+# @within asset_manager:object/call_method/run_method.m
+
+# 元のメソッド処理を呼び出す
+    function asset:object/1157.blight_flowgun/pre_hit/
diff --git a/Asset/data/asset/functions/object/alias/1157/recursive.mcfunction b/Asset/data/asset/functions/object/alias/1157/recursive.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/alias/1157/recursive
+#
+# メソッド処理のエイリアス
+#
+# @within asset_manager:object/call_method/run_method.m
+
+# 元のメソッド処理を呼び出す
+    function asset:object/1157.blight_flowgun/recursive/
diff --git a/Asset/data/asset/functions/object/alias/1157/register.mcfunction b/Asset/data/asset/functions/object/alias/1157/register.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/alias/1157/register
+#
+# Objectのデータ指定処理のエイリアス
+#
+# @within asset_manager:object/summon/register.m
+
+# 元の登録処理を呼び出す
+    function asset:object/1157.blight_flowgun/register
diff --git a/Asset/data/asset/tags/functions/artifact/click.carrot_on_a_stick.json b/Asset/data/asset/tags/functions/artifact/click.carrot_on_a_stick.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1316.blight_flowgun/trigger/1.trigger",
         "asset:artifact/1144.cradle_of_azure_moon/trigger/1.trigger",
         "asset:artifact/0005.musket_matchlock/trigger/1.trigger",
         "asset:artifact/0017.harmful_books/trigger/1.trigger",